Fonction LAMBDA
Syntaxe
=LAMBDA([paramètre1, paramètre2, …,] calcul)
| Argument | Description |
|---|---|
| paramètre | Une valeur que vous souhaitez transmettre à la fonction, comme une référence de cellule, une chaîne ou un nombre. Vous pouvez entrer jusqu’à 253 paramètres. Cet argument est facultatif. |
| calcul | La formule que vous souhaitez exécuter et renvoyer comme résultat de la fonction. Cette formule doit être le dernier argument et doit renvoyer un résultat. Il s’agit d’un argument obligatoire. |
Remarques
- Les noms et paramètres Lambda suivent les règles de syntaxe Excel pour les noms, à une exception près : il ne faut pas utiliser de point (.) dans le nom du paramètre. Si vous souhaitez en savoir plus, consultez l’article Noms dans les formules.
- Assurez-vous de suivre les meilleures pratiques lors de la création d’une fonction LAMBDA comme pour une formule Excel native, comme par exemple la transmission du nombre et du type d’arguments corrects, la correspondance des parenthèses ouvertes et fermées et la saisie de nombres non formatés. De plus, lorsque vous utilisez la commande Évaluer , Excel renvoie immédiatement le résultat de la fonction LAMBDA et vous ne pouvez pas cliquez sur Pas à pas détaillé. Si vous souhaitez en savoir plus, consultez l’article Détecter les erreurs dans les formules.
Erreurs
- Si vous entrez plus de 253 paramètres, Excel renvoie #VALEUR! comme erreur.
- Si un nombre incorrect d’arguments est transmis à une fonction LAMBDA, Excel renvoie #VALEUR! comme erreur.
- Si vous appelez une fonction LAMBDA en lui-même et que l’appel est circulaire, Excel peut retourner une #NUM! erreur s’il y a trop d’appels récursifs.
- Si vous créez une fonction LAMBDA dans une cellule sans l’appeler également à partir de cette cellule, Excel renvoie #CALC! comme erreur.
Créer une fonction LAMBDA
Voici un processus détaillé à suivre pour vous assurer que votre fonction Lambda fonctionne comme vous le souhaitez et que son comportement est similaire à celui d’une fonction Excel native.
Assurez-vous que la formule utilisée dans l’argument de calcul fonctionne correctement. Ceci est essentiel car lorsque vous créez la fonction LAMBDA, vous voulez vous assurer que la formule fonctionne et vous pouvez l’exclure si vous rencontrez des erreurs ou un comportement inattendu.
Une bonne pratique consiste à créer et tester votre fonction LAMBDA dans une cellule pour vous assurer qu’elle fonctionne correctement, notamment la définition et la transmission des paramètres. Pour éviter l’erreur #CALC!, ajoutez un appel à la fonction LAMBDA pour renvoyer immédiatement le résultat :
=Fonction LAMBDA ([paramètre1, paramètre2, …], calcul) (appel de fonction)
L’exemple suivant renvoie la valeur 2.
=LAMBDA(number, number + 1)(1)
Une fois la fonction LAMBDA finalisée, déplacez-la vers le gestionnaire de noms pour la définition finale. De cette façon, vous donnez à la fonction LAMBDA un nom significatif, fournissez une description et la rendez réutilisable à partir de n’importe quelle cellule du classeur. Vous pouvez également gérer la fonction LAMBDA comme pour n’importe quel nom, comme une constante de chaîne, une plage de cellules ou un tableau.
Procédure
- Effectuez l’une des opérations suivantes :
- Dans Excel pour Windows, sélectionnez Formules > Gestionnaire de noms.
- Dans Excel pour Mac, sélectionnez Formules > Définir le nom.
- Sélectionnez Nouveau, puis entrez les informations dans la boîte de dialogue Nouveau nom :
Nom : Entrez le nom de la fonction LAMBDA. Étendue : Le classeur est la valeur par défaut. Les feuilles de calcul individuelles sont également disponibles. Commentaire : Facultatif, mais vivement recommandé. Entrez jusqu’à 255 caractères. Décrivez brièvement l’objectif de la fonction ainsi que le nombre et le type d’arguments corrects.S’affiche dans la boîte de dialogue Insérer une fonction et sous forme d’info-bulle (avec l’argument Calcul ) lorsque vous tapez une formule et utilisez la Saisie semi-automatique des formules (aussi appelée Intellisense). Correspond à : Entrez la fonction LAMBDA. Par exemple :
- Pour créer la fonction LAMBDA, sélectionnez OK.
- Pour fermer la boîte de dialogue du Gestionnaire de noms, sélectionnez Fermer.
Si vous souhaitez en savoir plus, consultez l’article Utiliser le Gestionnaire de noms.
Exemples
Indiquez les éléments suivants dans le gestionnaire de noms :
| Nom : | EnCelsius |
| Étendue : | Classeur |
| Commentaire : | Convertir une température Fahrenheit en Celsius |
| Correspond à : | =LAMBDA(temp, (5/9) * (Temp-32)) |
Copiez les données de l’exemple dans le tableau suivant, et collez-les dans la cellule A1 d’une nouvelle feuille de calcul Excel. Si nécessaire, vous pouvez modifier la largeur des colonnes pour afficher toutes les données.
| Données | |
| 104 | |
| 86 | |
| 68 | |
| 50 | |
| 32 | |
| Formule | Résultat |
| =ENCELSIUS(A2) | 40 |
| =ENCELSIUS(A3) | 30 |
| =ENCELSIUS(A4) | 20 |
| =ENCELSIUS(A5) | 10 |
| =ENCELSIUS(A6) | 0 |
Indiquez les éléments suivants dans le gestionnaire de noms :
| Nom : | Hypotenuse |
| Étendue : | Classeur |
| Commentaire : | Renvoie la longueur de l’hypoténuse d’un triangle rectangle |
| Correspond à : | =LAMBDA(a, b, SQRT((a^2+b^2))) |
Copiez les données de l’exemple dans le tableau suivant, et collez-les dans la cellule A1 d’une nouvelle feuille de calcul Excel. Si nécessaire, vous pouvez modifier la largeur des colonnes pour afficher toutes les données.
| Données | |
| 3 | 4 |
| 5 | 12 |
| 7 | 24 |
| 9 | 40 |
| Formule | Résultat |
| =HYPOTENUSE(A2,B2) | 5 |
| =HYPOTENUSE(A3,B3) | 13 |
| =HYPOTENUSE(A4,B4) | 25 |
| =HYPOTENUSE(A5,B5) | 41 |
Indiquez les éléments suivants dans le gestionnaire de noms :
| Nom : | NombreDeMots |
| Étendue : | Classeur |
| Commentaire : | Renvoie le nombre de mots dans une chaîne de caractères |
| Correspond à : | =LAMBDA(text, LEN(TRIM(text)) – LEN(SUBSTITUTE(TRIM(text), ” “, “”)) + 1) |
Copiez les données de l’exemple dans le tableau suivant, et collez-les dans la cellule A1 d’une nouvelle feuille de calcul Excel. Si nécessaire, vous pouvez modifier la largeur des colonnes pour afficher toutes les données.
| Données | |
| Il vient par ici quelque maudit. | |
| Je suis venu, j’ai vu, j’ai vaincu. | |
| Le vif renard brun saute par-dessus le chien paresseux. | |
| Utilise la Force, Luke! | |
| Formule | Résultat |
| =COUNTWORDS(A2) | 5 |
| =COUNTWORDS(A3) | 6 |
| =COUNTWORDS(A4) | 9 |
| =COUNTWORDS(A5) | 4 |
Indiquez les éléments suivants dans le gestionnaire de noms :
| Nom : | DateThanksgiving |
| Étendue : | Classeur |
| Commentaire : | Renvoie la date de Thanksgiving aux États-Unis pour une année donnée |
| Correspond à : | =LAMBDA(year, TEXT(DATE(year, 11, CHOOSE(WEEKDAY(DATE(year, 11, 1)), 26, 25, 24, 23, 22, 28, 27)), “dd/mm/yyyy”)) |
Copiez les données de l’exemple dans le tableau suivant, et collez-les dans la cellule A1 d’une nouvelle feuille de calcul Excel. Si nécessaire, vous pouvez modifier la largeur des colonnes pour afficher toutes les données.
| Données | |
| 2020 | |
| 2021 | |
| 2022 | |
| 2023 | |
| 2024 | |
| Formule | Résultat |
| =DATETHANKSGIVING(A2) | 26/11/2020 |
| =DATETHANKSGIVING(A3) | 25/11/2021 |
| =DATETHANKSGIVING(A4) | 24/11/2022 |
| =DATETHANKSGIVING(A5) | 23/11/2023 |
| =DATETHANKSGIVING(A6) | 28/11/2024 |
